Perguntas valor da fatura

While !EOF()
	IncProc()

	dbSelectArea("SCK")
	dbSetOrder(1)
	dbSeek( (cAliasTRB)->CJ_FILIAL+(cAliasTRB)->CJ_NUM,.F.)

	//ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
	//³Inicializa a funcao fiscal                   ³
	//ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
	MaFisSave()
	MaFisEnd()
	MaFisIni(IIf(Empty((cAliasTRB)->CJ_CLIENT),(cAliasTRB)->CJ_CLIENTE,(cAliasTRB)->CJ_CLIENT),;// 1-Codigo Cliente/Fornecedor
		(cAliasTRB)->CJ_LOJA	,;	// 2-Loja do Cliente/Fornecedor
		"C"						,;	// 3-C:Cliente , F:Fornecedor
		"N"						,;	// 4-Tipo da NF
		(cAliasTRB)->A1_TIPO	,;	// 5-Tipo do Cliente/Fornecedor
		aRelImp					,;	// 6-Relacao de Impostos que suportados no arquivo
		Nil						,;	// 7-Tipo de complemento
		Nil						,;	// 8-Permite Incluir Impostos no Rodape .T./.F.
		"SB1"					,;	// 9-Alias do Cadastro de Produtos - ("SBI" P/ Front Loja)
		"MATA461")					// 10-Nome da rotina que esta utilizando a funcao

	While !Eof() .And. SCK->CK_NUM == (cAliasTRB)->CJ_NUM

		nItem ++

		MaFisAdd(SCK->CK_PRODUTO	,; 	// 1-Codigo do Produto ( Obrigatorio )
			SCK->CK_TES				,; 	// 2-Codigo do TES ( Opcional )
			SCK->CK_QTDVEN			,;	// 3-Quantidade ( Obrigatorio )
			SCK->CK_PRCVEN			,; 	// 4-Preco Unitario ( Obrigatorio )
			0						,; 	// 5-Valor do Desconto ( Opcional )
			""						,;	// 6-Numero da NF Original ( Devolucao/Benef )
			""						,;	// 7-Serie da NF Original ( Devolucao/Benef )
			0						,;	// 8-RecNo da NF Original no arq SD1/SD2
			0						,;	// 9-Valor do Frete do Item ( Opcional )
			0						,;	// 10-Valor da Despesa do item ( Opcional )
			0						,;	// 11-Valor do Seguro do item ( Opcional )
			0						,;	// 12-Valor do Frete Autonomo ( Opcional )
			SCK->CK_VALOR			,;	// 13-Valor da Mercadoria ( Obrigatorio )
			0						,;	// 14-Valor da Embalagem ( Opiconal )
			0						,;	// 15-RecNo do SB1 (Opcional)
			0						)	// 16-RecNo do SF4 (Opcional)

		dbSelectArea("SB1")
		dbSetOrder(1)
		dbSeek( xFilial("SB1")+SCK->CK_PRODUTO,.F.)

		dbSelectArea("TRB")
		RecLock("TRB",.T.)
		TRB->CODCLI		:= (cAliasTRB)->CJ_CLIENTE
		TRB->LOJACLI	:= (cAliasTRB)->CJ_LOJA
		TRB->NOMECLI	:= (cAliasTRB)->A1_NREDUZ
		TRB->UF			:= (cAliasTRB)->A1_EST
		TRB->ORCAMENTO 	:= (cAliasTRB)->CJ_NUM
		TRB->ITEM		:= SCK->CK_ITEM
		TRB->EMISSAO	:= (cAliasTRB)->CJ_EMISSAO
		TRB->TABELA 	:= (cAliasTRB)->CJ_TABELA
		TRB->DSCTAB 	:= (cAliasTRB)->CJ_DESC3 // Desconto Tabela
		TRB->DSCCML 	:= (cAliasTRB)->CJ_DESC2 // Desconto Comercial
		TRB->CONDPAG	:= (cAliasTRB)->CJ_CONDPAG +"-"+(cAliasTRB)->E4_DESCRI
		TRB->DSCFIN 	:= (cAliasTRB)->CJ_DESC1 // Desconto Financeiro
		TRB->ACRFINA	:= (cAliasTRB)->CJ_ACRFINA // Acrescimo Financeiro
		TRB->OVPRICE	:= (cAliasTRB)->CJ_OVPRICE // Over Price
		TRB->FRETE  	:= (cAliasTRB)->CJ_PERCFRT
		TRB->VLRFRETE	:= (cAliasTRB)->CJ_FRETE
		TRB->PERCSRV	:= (cAliasTRB)->CJ_PVLSERV // Percentual de Servico
		TRB->PRODUTO	:= SCK->CK_PRODUTO
		TRB->DESCRICAO	:= SB1->B1_DESC
		TRB->QTD		:= SCK->CK_QTDVEN
		TRB->VL_UNIT	:= SCK->CK_PRCVEN
		TRB->VL_TOT		:= SCK->CK_VALOR
		TRB->VL_TAB		:= SCK->CK_PRUNIT
		TRB->IPI		:= MaFisRet( nItem, "IT_ALIQIPI") //SB1->B1_IPI
		TRB->ICMS		:= MaFisRet( nItem, "IT_ALIQICM") //SB1->B1_PICM
		TRB->NCM		:= SB1->B1_POSIPI
		TRB->OPCIONAIS	:= SCK->CK_OPC
		TRB->FILIAL 	:= (cAliasTRB)->CJ_FILIAL
		MsUnlock()

		dbSelectArea("SCK")
		dbSkip()

	EndDo
	dbSelectArea(cAliasTRB)
	dbSkip() // Avanca o ponteiro do registro no arquivo

	MaFisEnd()
	MaFisRestore()
	nItem := 0

EndDo