Perguntas Dúvida Roberto Alves - WS Produto x Fornecedor

#INCLUDE "APWEBSRV.CH"
#INCLUDE "PROTHEUS.CH"
#INCLUDE "RWMAKE.CH"
#INCLUDE "TBICONN.CH"
#INCLUDE "TBICODE.CH"


//DADOS DE RETORNO OP METHODO GETOPDADOS
WSSTRUCT _RET      
	WSDATA   _cCodStatus    	AS string  OPTIONAL
	WSDATA   _cDescStatus		AS string  OPTIONAL
ENDWSSTRUCT  

//CRIA O WS
WSSERVICE WS_PSG1 DESCRIPTION "Web service para Integração"  

	
	//DADOS SA5
	WSDATA _acao As String
	WSDATA _codigo As String
	WSDATA _fornecedor As String
	WSDATA _loja As String
	WSDATA _referencia As String
	
	
	//DADOS DE RETORNO                      
	WSDATA _RET As _RET OPTIONAL
    //METHODOS DO WEBSERVERVICE
	WSMETHOD manutencaoProdFor   DESCRIPTION  "Efetua a manutenção na vinculação produto x fornecedor"
	
ENDWSSERVICE





WSMETHOD manutencaoProdFor WSRECEIVE _acao,_codigo,_fornecedor,_loja,_referencia WSSEND _RET WSSERVICE WS_PSG1
  	Local aArea     := GetArea()  
  	Local lWsReturn := .T.   
	Local aDados := {}
	Local cMsg := ""
	lMsErroAuto := .F.
  	
  	
	RPCSetType(3) 
        PREPARE environment EMPRESA ("01") FILIAL ("01") MODULO "COM"
  	SetModulo("SIGACOM","COM")
  	
  	::_RET     := WSClassNew('_RET')
  	
 
	aAdd(aDados,{"A5_PRODUTO",::_codigo,Nil})
  	aAdd(aDados,{"A5_FORNECE",::_fornecedor,Nil})
  	aAdd(aDados,{"A5_LOJA",::_loja,Nil})
  	aAdd(aDados,{"A5_CODPRF",::_referencia,Nil})
  //	aAdd(aDados,{"A5_SITU","B",Nil})    //<- NAO UTILIZAMOS MODULO SIGAQIE
  	
  	
  	
  	IF ::_acao == "I"
  		cMsg := "Registro incluido com sucesso!"
  		MSExecAuto({|x,y| Mata060(x,y)},aDados,3) //Inclusao
  	ELSEIF ::_acao == "A"
  		cMsg := "Registro alterado com sucesso!"
  		MSExecAuto({|x,y| Mata060(x,y)},aDados,4) //Aletaracao  	
  	ELSEIF ::_acao == "E"
  	  	cMsg := "Registro apagado com sucesso!"
  		MSExecAuto({|x,y| Mata060(x,y)},aDados,5) //Exclusao  	  	
  	ENDIF
  	
  	IF lMsErroAuto
     	::_RET:_cCodStatus     := "999"
		::_RET:_cDescStatus    := MostraErro()
	ELSE
        ::_RET:_cCodStatus     := "100"
		::_RET:_cDescStatus    := cMsg
	ENDIF
	
	RESET ENVIRONMENT
	
	RestArea(aArea)   
Return(lWsReturn)