Perguntas Chamada da função de Visualização da NFE no Faturamento

Function Mc090Visual(cAlias,nReg,nOpc)

Local aArea      := GetArea()
Local aAreaSA1   := SA1->(GetArea())
Local aAreaSA2   := SA2->(GetArea())
Local aAreaSD2   := SD2->(GetArea())

Local lQuery     := .F.
Local cAliasSD2  := "SD2"

#IFDEF TOP
	Local cQuery     := ""
#ENDIF	

//ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
//³ Salva a pilha da funcao fiscal                               ³
//ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
MaFisSave()
MaFisEnd()

dbSelectArea("SD2")
dbSetOrder(3)
#IFDEF TOP
	
	If TcSrvType() <> "AS/400"

		cAliasSD2 := CriaTrab(,.F.)
		lQuery := .T.
		cQuery := "SELECT D2_FILIAL,D2_DOC,D2_SERIE,D2_CLIENTE,D2_LOJA,D2_TIPO,R_E_C_N_O_ SD2RECNO "
		cQuery += "FROM "+RetSqlName("SD2")+" SD2 "
		cQuery += "WHERE SD2.D2_FILIAL='"+xFilial("SD2")+"' AND "
		cQuery += "SD2.D2_DOC='"+SF2->F2_DOC+"' AND "
		cQuery += "SD2.D2_SERIE='"+SF2->F2_SERIE+"' AND "
		cQuery += "SD2.D2_CLIENTE='"+SF2->F2_CLIENTE+"' AND "
		cQuery += "SD2.D2_LOJA='"+SF2->F2_LOJA+"' AND "
		cQuery += "SD2.D2_TIPO='"+SF2->F2_TIPO+"' AND "
		cQuery += "SD2.D_E_L_E_T_=' ' "
		cQuery += "ORDER BY "+SqlOrder(SD2->(IndexKey()))
		
		cQuery := ChangeQuery(cQuery)
		
		dbUseArea(.T.,"TOPCONN",TcGenQry(,,cQuery),cAliasSD2,.T.,.T.)
	Else		
#ENDIF
		MsSeek(xFilial("SD2")+SF2->F2_DOC+SF2->F2_SERIE+SF2->F2_CLIENTE+SF2->F2_LOJA)
#IFDEF TOP
	Endif	
#ENDIF

While !Eof() .And. xFilial("SD2") == (cAliasSD2)->D2_FILIAL .And.;
	SF2->F2_DOC == (cAliasSD2)->D2_DOC .And.;
	SF2->F2_SERIE == (cAliasSD2)->D2_SERIE .And.;
	SF2->F2_CLIENTE == (cAliasSD2)->D2_CLIENTE .And.;
	SF2->F2_LOJA == (cAliasSD2)->D2_LOJA
	If SF2->F2_TIPO == (cAliasSD2)->D2_TIPO
		If lQuery
			SD2->(MsGoto((cAliasSD2)->SD2RECNO))
		EndIf
		A920NFSAI("SD2",SD2->(RecNo()),0)
		Exit
	EndIf
	dbSelectArea(cAliasSD2)
	dbSkip()
EndDo
If lQuery
	dbSelectArea(cAliasSD2)
	dbCloseArea()
	dbSelectArea("SD2")	
EndIf
//ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
//³ Restaura a pilha da funcao fiscal                            ³
//ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
MaFisRestore()
RestArea(aAreaSD2)
RestArea(aAreaSA2)
RestArea(aAreaSA1)
RestArea(aArea)

Return (.T.)