1. Fórum
  3. Protheus/Microsiga/Totvs
  5. AdvPL (Advanced Protheus Language)
  7. Dúvidas Gerais
  9. impressora zebra
× Linguagem de Programação ADVPL

Perguntas impressora zebra

Mais
11 anos 6 meses atrás #14160 por hlaterza
impressora zebra foi criado por hlaterza
BOM DIA

ESTOU COM A SEGUINTE IMPRESSÃO

GOSTARIA DE COLOCAR UM FONTE DIFERENTE NA IMPRESSÃO DA EMPRESA. COMO FAZER??


MSCBSAY(35,05,"EMPRESA" ,"N","0","070,070")
MSCBSAY(05,20,cNome ,"N","0","050,050")
MSCBSAY(05,30,"CNPJ: "+cCNPJ ,"N","0","060,060")
MSCBSAY(05,40,cEND ,"N","0","045,045")
MSCBSAY(05,50,"CEP: "+cCEP ,"N","0","060,060")
MSCBSAY(05,60,cMUN+" - "+cEST ,"N","0","060,060")
MSCBSAY(20,80,"NF: "+cDOC ,"N","0","120,120")

OBRIGADO

Por favor Acessar ou Registrar para participar da conversa.

Mais
11 anos 6 meses atrás #14187 por andre_rocha
Respondido por andre_rocha no tópico impressora zebra
O número "0" que voce passa como parametro eh a fonte... fora essa voce pode utilizar de "A" ate "H".

Por favor Acessar ou Registrar para participar da conversa.

Mais
11 anos 5 meses atrás #14384 por lalberto
Respondido por lalberto no tópico impressora zebra
Horacio para impressora zebra vc pode usar o tmsprinter, segue um exemplo, ai vc usa qualquer fonte inclusive impressão de imagens.

Abraços

//
//
oPrint := TMSPrinter():New("Etiquetas de Produtos")
oPrint:Setup()
oPrint:SetPortrait()
// Fonte Tamanho Negrito
oFont8 := TFont():New("Arial", 9, 08, .T., .F., 5,,, .T., .F.,,,,,, oPrint)
oFont8n := TFont():New("Arial", 9, 08, .T., .T., 5,,, .T., .F.,,,,,, oPrint)
oFont9 := TFont():New("Arial", 9, 09, .T., .F., 5,,, .T., .F.,,,,,, oPrint)
oFont9n := TFont():New("Arial", 9, 09, .T., .T., 5,,, .T., .F.,,,,,, oPrint)
oFont10 := TFont():New("Arial", 9, 10, .T., .F., 5,,, .T., .F.,,,,,, oPrint)
oFont10n := TFont():New("Arial", 9, 10, .T., .T., 5,,, .T., .F.,,,,,, oPrint)
oFont12 := TFont():New("Arial", 9, 12, .T., .F., 5,,, .T., .F.,,,,,, oPrint)
oFont12n := TFont():New("Arial", 9, 12, .T., .T., 5,,, .T., .F.,,,,,, oPrint)
oFont13 := TFont():New("Arial", 9, 13, .T., .F., 5,,, .T., .F.,,,,,, oPrint)
oFont13n := TFont():New("Arial", 9, 13, .T., .T., 5,,, .T., .F.,,,,,, oPrint)
oFont14 := TFont():New("Arial", 9, 14, .T., .F., 5,,, .T., .F.,,,,,, oPrint)
oFont14n := TFont():New("Arial", 9, 14, .T., .T., 5,,, .T., .F.,,,,,, oPrint)
oFont16 := TFont():New("Arial", 9, 16, .T., .F., 5,,, .T., .F.,,,,,, oPrint)
oFont16n := TFont():New("Arial", 9, 16, .T., .T., 5,,, .T., .F.,,,,,, oPrint)
oFont18 := TFont():New("Arial", 9, 18, .T., .F., 5,,, .T., .F.,,,,,, oPrint)
oFont18n := TFont():New("Arial", 9, 18, .T., .T., 5,,, .T., .F.,,,,,, oPrint)
oFont24 := TFont():New("Arial", 9, 24, .T., .F., 5,,, .T., .F.,,,,,, oPrint)
oFont24n := TFont():New("Arial", 9, 24, .T., .T., 5,,, .T., .F.,,,,,, oPrint)
//
oBrush := TBrush():New("", 4)
//

oPrint:StartPage()

SB1->(dbSetOrder(1), dbSeek(xFilial("SB1")+xCols[nItem,2]))
SC6->(dbSetOrder(2), dbSeek(xFilial("SC6")+SB1->B1_COD+SC5->C5_NUM))

nLinha := 070 // Linha InItemcial em Pixels
nColuna := 050 // Coluna InItemcial em Pixels

oPrint:sayBitmap(nLinha,nColuna,"logo.bmp",330,120)

cDesc := AllTrim(SB1->B1_COD)+' - ' + SB1->B1_DESC
nLinha := 060
For nx:=1 to MlCount(cDesc,30)
oPrint:Say(nLinha,400,MemoLine(cDesc,30,nx),oFont12n,,0)
nLinha += 60
Next

nLinha += 080
oPrint:Say(nLinha, nColuna, SC5->C5_CLIENTE+'/'+SC5->C5_LOJACLI+' - ' + Capital(Posicione("SA1",1,xFilial("SA1")+SC5->C5_CLIENTE+SC5->C5_LOJACLI,"A1_NOME")), oFont10n)

nLinha += 070
oPrint:Say(nLinha, nColuna, "Fone:", oFont10)
oPrint:Say(nLinha, nColuna+100, SA1->A1_DDD + ' ' + SA1->A1_TEL, oFont10n)
If Empty(SC5->C5_NOTA)
oPrint:Say(nLinha, nColuna+400, "Pedido:", oFont10)
oPrint:Say(nLinha, nColuna+530, SC5->C5_NUM, oFont10n)
Else
oPrint:Say(nLinha, nColuna+400, "Nota:", oFont10)
oPrint:Say(nLinha, nColuna+530, SC5->C5_NOTA+'/'+SC5->C5_SERIE, oFont10n)
Endif
oPrint:Say(nLinha, nColuna+800, "Peso:", oFont10)
oPrint:Say(nLinha, nColuna+900, TransForm(Round(xCols[nItem,5]*SB1->B1_PESO,4),"@E 99,999.9999"), oFont10n)

nLinha += 060
oPrint:Say(nLinha, nColuna, "Unidade:", oFont10)
oPrint:Say(nLinha, nColuna+160, SB1->B1_UM, oFont10n)

oPrint:Say(nLinha, nColuna + 300, "Qtde:", oFont10)
oPrint:Say(nLinha, nColuna+400, TransForm(xCols[nItem,5],PesqPict("SC6","C6_QTDVEN")), oFont10n)
nLinha += 060
oPrint:Say(nLinha, nColuna, "No Pedido Cliente:", oFont10)
oPrint:Say(nLinha, nColuna+300, SC5->C5_PEDCLI, oFont10n)
nLinha += 060
oPrint:Say(nLinha, nColuna, "Cód.Prod.Cliente::", oFont10)
If SA7->(dbSetOrder(2), dbSeek(xFilial("SA7")+SB1->B1_COD+SC5->C5_CLIENTE+SC5->C5_LOJACLI))
oPrint:Say(nLinha, nColuna+300, SA7->A7_CODCLI, oFont10n)
Endif
cCodBar := Iif(!Empty(SB1->B1_CODBAR),SB1->B1_CODBAR,'7898472230017')

// MSBAR("EAN13" ,4.6,8.5,cCodBar,oPrint,/*lCheck*/,/*Color*/,/*lHorz*/,nItemL,1,.F.,nItemL,nItemL,.F.)
// MsBar("EAN13" ,3.6,5.5,cCodBar,oPrint,.F.,,,0.040,1.0,,,,.T.)
MSBAR("INT25" ,3.6,5.5,Alltrim(cCodBar),oPrint,.F.,,.T.,0.028,0.9,,,"A",.F.) // Tiago se vira

oPrint:EndPage()
Luiz Alberto Vieira Alves
Proprietário
55 (12) 9 8256-5905 (Vivo)
www.3lsystems.com.br
www.masteradvpl.com.br

Por favor Acessar ou Registrar para participar da conversa.

Mais
11 anos 5 meses atrás #14486 por henry.charriere
Respondido por henry.charriere no tópico impressora zebra
#Include "PROTHEUS.CH"
#Include "RWMAKE.CH"

User Function REST002()

Local oReport
Private cPerg := 'REST002'

CriaSx1(cPerg)
Pergunte(cPerg,.T.)
Processa({ || xPrintRel(),OemToAnsi('Gerando o relatório.')}, OemToAnsi('Aguarde...'))

Return

Static Function xPrintRel()

Local nX := 0
Local nQtdPag := 0

Private oPrint
Private cAlias := getNextAlias() //cria um alias temporário
Private oFont06 := TFont():New('Arial',,06,,.F.,,,,.F.,.F.)
Private oFont06n := TFont():New('Arial',,06,,.T.,,,,.F.,.F.)
Private oFont08 := TFont():New('Arial',,08,,.F.,,,,.F.,.F.)
Private oFont08n := TFont():New('Arial',,08,,.T.,,,,.F.,.F.)
Private oFont10 := TFont():New('Arial',,10,,.F.,,,,.F.,.F.)
Private oFont10n := TFont():New('Arial',,10,,.T.,,,,.F.,.F.)
Private oFont12 := TFont():New('Arial',,12,,.F.,,,,.F.,.F.)
Private oFont12n := TFont():New('Arial',,12,,.T.,,,,.F.,.F.)
Private oFont14 := TFont():New('Arial',,14,,.F.,,,,.F.,.F.)
Private oFont14n := TFont():New('Arial',,14,,.T.,,,,.F.,.F.)
Private oFont26 := TFont():New('Arial',,26,,.F.,,,,.F.,.F.)
Private oFont26n := TFont():New('Arial',,26,,.T.,,,,.F.,.F.)
Private nLin := 0

BeginSql Alias cAlias
SELECT
B1_COD,
B1_DESC
FROM
%table:SB1%
WHERE
B1_FILIAL = %xFilial:SB1%
AND B1_COD >= %exp:mv_par01%
AND B1_COD <= %exp:mv_par02%

ORDER BY
B1_COD
EndSql

(cAlias)->(dbGoTop())

oPrint := TMSPrinter():New(OemToAnsi('Etiqueta de produto'))
oPrint:SetPortrait()

//1cm +/- 117,5 px

//nQtdPag := (mv_par03 % 2)
//iif(nQtdPag = 0, nQtdPag := Int(mv_par03/2), nQtdPag := Int(mv_par03/2) + 1)

While !(cAlias)->(Eof())

oPrint:StartPage()

nLin := 0030
oPrint:Say(nLin,0299,OemToAnsi('COD: ' + alltrim((cAlias)->B1_COD)),oFont10n,,,,0)

nLin += 0030

oPrint:Say(nLin,0299,alltrim((cAlias)->B1_DESC),oFont10,,,,0)
MSBAR('CODE128',1.4,1.5,alltrim((cAlias)->B1_COD),oPrint,.F.,,.T.,0.080,5.6,,,,.F.)


oPrint:EndPage()
(cAlias)->(dbSkip())

enddo

(cAlias)->(dbCloseArea())

oPrint:Preview()
oPrint:end()
Return

Static Function CriaSx1(cPerg)
PutSx1(cPerg,"01","Do Código Interno?" ,"Do Código Interno?" ,"Do Código Interno?" ,"mv_ch1","C",15,0,0,"G","","SB1","","","mv_par01")
PutSx1(cPerg,"02","Até Código Interno?" ,"Até Código Interno?","Até Código Interno?","mv_ch2","C",15,0,0,"G","","SB1","","","mv_par02")
//PutSx1(cPerg,"03","Qtde Etiquetas" ,"Qtde Etiquetas" ,"Qtde Etiquetas" ,"mv_ch3","N",05,0,0,"G","","" ,"","","mv_par03")
return

Por favor Acessar ou Registrar para participar da conversa.

  1. Fórum
  3. Protheus/Microsiga/Totvs
  5. AdvPL (Advanced Protheus Language)
  7. Dúvidas Gerais
  9. impressora zebra
Tempo para a criação da página:0.133 segundos
Joomla templates by a4joomla