Perguntas Abrir arquivo no navegador

/*
Funcao      : ExportXml
Objetivos   : Exporta XML
Autor       : Kanaãm L. R. Rodrigues 
Data/Hora   : 07/07/2011
*/
*-------------------------------------------------*
Static Function ExportXml(cApp, nTpExp)
*-------------------------------------------------*
Local oDlg1 
Local oIBrowser
Local aPos      := {}
Local cMemo     := ""
Local cArq      := CriaTrab(,.F.)+".XML"
Local cDest     := GetTempPath()+cArq
Local nArq
Local nRmtType  := GetRemoteType()
Local lBrw      := GETMV('MV_ZBRWRSA',,.T.) 
Local lBrwIni


//cria o arquivo XML
nArq := FCreate(cArq)             

//verifica se o arquivo foi criado
If nArq == -1
   MsgStop("Não foi possível criar o arquivo!"+ENTER+;
           "Arquivo: "+cArq)
   Return
EndIf

//alimenta o cMemo de acordo com a opção escolhida
Do Case
//
   Case nTpExp == 1 //XML Enviado
      cMemo := M->ZR1_VMXMLE
   Case nTpExp == 2 //XML Recebido
      cMemo := M->ZR1_VMXMLR
   Case nTpExp == 3 //XML SOAP
      cMemo := M->ZR1_VMXMLS
//      
EndCase

//preenche com o texto do memo e fecha o arquivo
FWrite(nArq,cMemo)
Fclose(nArq)

//configura a variavel lBrwIni de acordo com o tipo de client (LINUX/WINDOWS/ETC)
If lBrwIni == nil
   If nRmtType == 2 //LINUX
      lBrwIni := .F.
   Else //verifica configuração da chave browserenabled no INI
  	  lBrwIni := (GetPvProfString("CONFIG","BROWSERENABLED","ERRO",GetRemoteIniName()) == "1")
   EndIf
EndIf

//copia o arquivo para o temp do usuário deletando o anterior, caso não consiga copiar
//emite mensagem de erro automaticamente.
If AvCpyFile(cArq, cDest, .T., .T.)
   //abre arquivo no formato Web
   If cApp == "iexplore.exe"
      //verifica se o browse está habilitado no parametro e no INI
      If lBrw .AND. lBrwIni
         oMainWnd:ReadClientCoords()
         Define MsDialog oDlg1 Title cDest From oMainWnd:nTop-10    ,oMainWnd:nLeft     To ;
                                                oMainWnd:nBottom-40 ,oMainWnd:nRight-10 Of oMainWnd Pixel
            //
            aPos := PosDlg(oDlg1)	
            oIBrowser := tIBrowser():New(aPos[1]-15,aPos[2],aPos[4],aPos[3]-5,cDest,oDlg1)
		    //
         Activate MsDialog oDlg1
      //abre o IE com o arquivo XML   
      ElseIf nRmtType == 2  .OR. !lBrw //LINUX ou parametro .F. 
         ShellExecute("open",cDest,"","",5) 
      //caso o ini não esteja configurado   
      ElseIf !lBrwIni
         MsgStop("SmartClient.ini não configurado corretamente."+ENTER+;
                 "verificar chave 'BROWSERENABLED'")
      EndIf
   //abre o notepad com o arquivo XML
   Else 
      WinExec(cApp+" "+cDest) 
   EndIf
EndIf
//
Return