Perguntas Impressao de etiqueta de volumes

Olá Eder seja bem vindo ao Master Advpl, olha tem esse exemplo na área de downloads veja se te ajuda ok.

masteradvpl.com.br/index.php/downloads/v...essora-termica-zebra

Cara vou ver se acho alguma coisa e te mando ok.

Abraços.

Segue essa função, espero que ajude.


User Function NESTR21b(_cPedido,_nVolumes,_dData,_cConf,_nEDe,_nEAte,_cNotaFis)
Local _aArea := GetArea()
Local _nX := 0
Local _nXP := 0
Local _nXIni := 1
Local _nEtiqs := 0
Local _cNome := ""
Local _cEndCli := ""
Local _cBaiCli := ""
Local _cCepCli := ""
Local _cMunCli := ""
Local _cEstCli := ""
Local _cRegCli := ""
Local _lReImp := .F.
Local _cPed := _cPedido

cPorta := "LPT1"
cModelo := "S4M"

MSCBPRINTER(cModelo,cPorta,,,.f.)
MSCBCHKSTATUS(.F.)

_nInicio := 1
_nFinal := MV_PAR02
_nInicio2:= 1
_nFinal2 := MV_PAR02

If _nEDe <> Nil
_nInicio := _nEDe
_nInicio2:= _nEDe
Endif
If _nEAte <> Nil
_nFinal := _nEAte
_nFinal2 := _nEAte
Endif

_aPedEti := {}
If !Empty(_cNotaFis)
SD2->(DbSetOrder(3))
If SD2->(DbSeek(xFilial("SD2")+_cNotaFis))
While SD2->(!Eof()) .And. xFilial("SD2")+_cNotaFis == SD2->(D2_FILIAL+D2_DOC+D2_SERIE)
If AsCan(_aPedEti,SD2->D2_PEDIDO) = 0
AaDd(_aPedEti,SD2->D2_PEDIDO)
Endif
SD2->(DbSkip())
EndDo
Endif
ElseIf !Empty(_cPedido)
AaDd(_aPedEti,SD2->D2_PEDIDO)
Endif

_nEtiNF := 0

For _nX := 1 To Len(_aPedEti)
DbSelectArea("SC5")
DbSetOrder(1)
DbSeek(xFilial('SC5')+_aPedEti[_nX])

If !Empty(SC5->C5_IMPETIQ)
_lReImp := .T.
Endif

RecLock("SC5",.F.)
SC5->C5_IMPETIQ := IIf(Empty(SC5->C5_USUETIQ),"N","S")
SC5->C5_USUETIQ := CUSERNAME
SC5->C5_DTETIQ := dDatabase
SC5->C5_HORETIQ := Time()
SC5->(MsUnLock())

SA1->(DbSetOrder(1))
If SA1->(DbSeek(xFilial("SA1")+SC5->(C5_CLIENTE+C5_LOJACLI)))
_cNome := SA1->A1_NOME
_cRegCli := Tabela("A2",SA1->A1_REGIAO,.F.)
_nRegSA1 := SA1->(Recno())
Endif
If !Empty(SC5->(C5_CLIENT+C5_LOJAENT)) .And. SC5->(C5_CLIENTE+C5_LOJACLI) <> SC5->(C5_CLIENT+C5_LOJAENT) .And. SA1->(DbSeek(xFilial("SA1")+SC5->(C5_CLIENT+C5_LOJAENT)))
_cEndCli := SA1->A1_END
_cBaiCli := SA1->A1_BAIRRO
_cCepCli := SA1->A1_CEP
_cMunCli := SA1->A1_MUN
_cEstCli := SA1->A1_EST
_cRegCli := Tabela("A2",SA1->A1_REGIAO,.F.)
Else
SA1->(DbGoTo(_nRegSA1))
_cEndCli := SA1->A1_END
_cBaiCli := SA1->A1_BAIRRO
_cCepCli := SA1->A1_CEP
_cMunCli := SA1->A1_MUN
_cEstCli := SA1->A1_EST
_cRegCli := Tabela("A2",SA1->A1_REGIAO,.F.)
EndIf

_cNota := SC5->C5_NOTA
_cSerNota := SC5->C5_SERIE

If !Empty(_cNotaFis)
_nInicio := 1
_nFinal := SC5->C5_VOLUME1
Endif

For _nXP := _nInicio To _nFinal

_nEtiNF++

If !Empty(_cNotaFis) .And. (_nEtiNF < _nInicio2 .Or. _nEtiNF > _nFinal2)
Loop
Endif

MSCBBEGIN(1,4)

MSCBSAY(04,04,"PEDIDO","N","2","20,20")
MSCBSAY(04,10,_aPedEti[_nX],"N","2","110,110")
MSCBSAYBAR(75,04,Rtrim(_aPedEti[_nX]),"N","MB07",10,.F.,.F.,,,4,2)
MSCBSAY(04,24,_cNome,"N","2","20,20")
MSCBSAY(04,32,"Entrega:","N","2","20,20")
MSCBSAY(04,38,_cEndCli,"N","2","15,15")
MSCBSAY(04,43,_cBaiCli,"N","2","15,15")
MSCBSAY(04,48,_cMunCli+" - "+_cEstCli,"N","2","15,15")
MSCBSAY(04,53,_cCepCli,"N","2","15,15")
MSCBSAY(50,58,"NF","N","2","25,25")
MSCBSAY(65,58,Alltrim(_cNota)+"/"+Alltrim(_cSerNota),"N","2","25,25")
MSCBSAY(04,65,"Volume:","N","2","70,70")
If !Empty(_cNotaFis)
MSCBSAY(70,65,Alltrim(Str(_nXP))+"/"+Alltrim(Str(_nFinal)),"N","2","55,55")
MSCBSAY(70,75,Alltrim(Str(_nEtiNF))+"/"+Alltrim(Str(_nFinal2)),"N","2","55,55")
Else
MSCBSAY(70,65,Alltrim(Str(_nXP))+"/"+Alltrim(Str(_nFinal)),"N","2","110,110")
Endif
MSCBSAY(04,80,_cRegCli,"N","2","110,110")
If _lReImp
MSCBSAY(70,95,"REIMPRESSAO","N","2","15,15")
Endif
MSCBSAY(04,100,DTOC(dDatabase),"N","2","15,15")
MSCBSAY(40,100,Time(),"N","2","15,15")
MSCBSAY(70,100,CUSERNAME,"N","2","15,15")
// MSCBLineH(06,20,089,3,"B")
// MSCBLineV(06,20,089,3,"B")

MSCBEND() // Finaliza a formacao da imagem da etiqueta

Next
Next

MSCBCLOSEPRINTER()

RestArea(_aArea)

Return