× Linguagem de Programação ADVPL

Perguntas Loop for não funciona

Mais
7 anos 6 meses atrás #31120 por raisiqueira
Pessoal, meu loop for não está funcionando. Quando dou o comando para imprimir X quantidade, não imprime, sai apenas uma etiqueta:
DbSelectArea("SF2")
	SF2->(DbSetOrder(1))
	SF2->(DbGoTop())
	
	IF !SF2->(MsSeek(xFilial("SF2")+cDoc+cSerie))
		MsgAlert("NF/Serie "+cDoc+"/"+cSerie+" n�o encontrada!")
		Return
	Else
		cTransp		:= POSICIONE("SA4",1,xFilial("SA4")+SF2->F2_TRANSP,"A4_NOME")
		cCliente	:= POSICIONE("SA1",1,xFilial("SA1")+SF2->F2_CLIENTE+SF2->F2_LOJA,"A1_NOME")
		nVol		:= SF2->F2_VOLUME1
		
		IF Empty(nQuant)
			nQuant := SF2->F2_VOLUME1
		Endif
	EndIf
	
	If Empty(nQuant)
		MsgAlert("Volume da NF est� zerado!")
		Return
	Endif
	
	SF2->(DbCloseArea())
	
	If Empty(cLocImp) .or. ! u_P_CB5Set(cLocImp)
		MsgAlert("Local de Impress�o "+ cLocImp +" nao Encontrado!") //
	Else
		For x := 1 to nQuant
			MSCBBEGIN(nEtiq,6)
			MSCBBEGIN(nEtiq,6)
			//      X   Y  STRING          N   2   TAMANHO
			MSCBSAY(04,80,SM0->M0_NOMECOM,"N","3","1.4,1")
			MSCBSAY(35,75,"CNPJ: " + Transform(SM0->M0_CGC,"@R 99.999.999/9999-99"),"N","2","1,1")
			MSCBSAY(35,60,"Insc. Estadual: " + SM0->M0_INSC,"N","2","1,1")
			MSCBSAY(06,65,Replicate("_",60),"N","2","1,1")
			MSCBSAY(06,55,"NF: "+ALLTRIM(cDoc)+"/"+ALLTRIM(cSerie)+" VOL: "+alltrim(str(nVol)),"N","3","1.5,1")
			MSCBSAY(06,40,cTransp,"N","3","1.4,1")
			MSCBSAY(06,30,Replicate("_",60),"N","2","1,1")
			MSCBSAY(06,20,"CLIENTE:","N","3","1.4,1")
			MSCBSAY(06,10,SubStr(cCliente,1,20),"N","3","1.5,1")
			If Len(Alltrim(cCliente)) > 20
				MSCBSAY(06,05,SubStr(cCliente,20,20),"N","3","1.5,1")
			EndIf
			MSCBEND()
			MSCBCLOSEPRINTER()
		Next x
	Endif

Por favor Acessar ou Registrar para participar da conversa.

Mais
7 anos 6 meses atrás #31122 por admin
Respondido por admin no tópico Loop for não funciona
COLOCA O MSCBCLOSEPRINTER() DEPOIS DO NEXT E NO COMEÇO DO FOR DEIXA APENAS UM

MSCBBEGIN(nEtiq,6) TEM DUAS VEZES.

Por favor Acessar ou Registrar para participar da conversa.

Mais
7 anos 6 meses atrás #31139 por raisiqueira
Respondido por raisiqueira no tópico Loop for não funciona
Valeu, deu certo!

Por favor Acessar ou Registrar para participar da conversa.

Tempo para a criação da página:0.099 segundos
Joomla templates by a4joomla